COMMENT ⊗   VALID 00005 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002		TITLE TAPEIT
C00004 00003	INFIL:	OUTSTR [ASCIZ/
C00006 00004	RNUM:	INCHWL C
C00007 00005	GETNAM:	MOVEI A,
C00036 ENDMK
C⊗;
	TITLE TAPEIT
	EXTERN JOBREL,JOBFF
A←1 ↔ B←2 ↔ C←3 ↔ D←4
E←5 ↔ U←7 ↔ P←17
EOC←1200 ↔ LPDL←←69
LMAR←←=0 ↔ RMAR←←=1699 ↔ WIDTH←←=1700
LBUFL←←=48 ↔ LSTBIT←←1⊗34
OVERLAP←←=50 ↔ DOFF←←-=760

GETTAP:	INIT 12,617
	SIXBIT/MTA0/
	0
	HALT
	MOVE P,[-LPDL,,PDL-1]
	HRRZI E,EOC+177
	CORE E,
	EXIT
BEG:	INCHWL E
	CAIN E,111
	JRST INFIL
	CAIN E,102
	JRST BACKSP
	CAIE E,106
	JRST BEG
	CLOSE 12,	;FINISH
	STATZ 12,740000
	0
	RELEASE 12,
	EXIT

BACKSP:	INIT 12,617
	SIXBIT/MTA0/
	0
	HALT
	MTAPE 12,7
	JRST BEG

SIGN:	0
FILNAM:	0
FILEXT:	0
	0
FILPPN:	0

PDL:	BLOCK LPDL

INPO:	IOWD 200,EOC

INFIL:	OUTSTR [ASCIZ/
	FILE = /]
	SETZM FILEXT+1
	SETZM FILPPN
	MOVSI A,'BIT'
	MOVEM A,FILEXT
	PUSHJ P,GETNAM
	SKIPN A
 	MOVE A,['PLT   ']
    	MOVEM A,FILNAM
	CAIE C,"."
	JRST NOEXTN
	PUSHJ P,GETNAM
	MOVEM A,FILEXT
NOEXTN:	CAIE C,"["
	JRST FFDX
	PUSHJ P,GETP
	HRLZM A,FILPPN
	PUSHJ P,GETP
	HRRM A,FILPPN
FFDX:	INCHRW C
	CAIE C,12
	JRST FFDX
	OPEN [17↔'DSK   '↔0]
	JRST 4,.
	LOOKUP FILNAM
	JRST INFIL
	MOVE U,INPO
	SETZ 10,
	INPUT U
	HRRZ U,EOC+1
	HRRZI E,EOC+2(U)
	SUBI U,200
	JUMPLE U,CLOZE
	CORE E,
	JRST INFIL
	IORI U,177
	MOVNS U
	HRLZI U,-1(U)
	HRRI U,EOC+177
	INPUT U
CLOZE:	RELEAS
			;CHANGE FORMAT HERE←←←
	HRRZ U,EOC+1
	HRLZI U,-1(U)
	HRRI U,EOC+1

TOTAPE:	OUTPUT 12,U
	STATZ 12,740000
	0
	JRST BEG

RNUM:	INCHWL C
	CAIN C,15
	JRST RNUM
	CAIN C,12
	POPJ P,
	AOS (P)
	MOVEI A,
	SETZM SIGN
	CAIN C,"-"
	JRST [	PUSHJ P,RNUML
		SETOM SIGN
		MOVN A,A
		POPJ P,]
	CAIN C,"+"
RNUML:	INCHWL C
	CAIL C,"0"
	CAILE C,"9"
	JRST RNUMX
	IMULI A,12
	ADDI A,-"0"(C)
	JRST RNUML

RNUMX:	CAIN C,15
	INCHRW C
	POPJ P,

GETNAM:	MOVEI A,
	MOVE B,[440600,,A]
GETNML:	PUSHJ P,RCH
	POPJ P,
	SUBI C,40
	TLNE B,770000
	IDPB C,B
	JRST GETNML

GETP:	MOVEI A,
GETPL:	PUSHJ P,RCH
	POPJ P,
	TRNE A,770000
	JRST GETPL
	LSH A,6
	ADDI A,-40(C)
	JRST GETPL

RCH:	INCHWL C
	CAIN C,42
	JRST RCHQ
	CAIE C,11
	CAIN C," "
	JRST RCH
	CAIE C,"."
	CAIN C,","
	POPJ P,
	CAIE C,"["
	CAIN C,"]"
	POPJ P,
RCHQR:	CAIGE C,40
	POPJ P,
	CAIL C,"a"
	CAILE C,"z"
	CAIA
	SUBI C,40
POPJ1:	AOS (P)
	POPJ P,

RCHQ:	INCHWL C
	JRST RCHQR

	END GETTAP